Example 5.8 (A Diagonal with No Critical Points)

Studying a rational function with no critical points in the main diagonal direction. Requirements: None

# Define the polynomial under consideration and the system defining contour points
var('x,y')
H = 2+y-x*(1+y)^2
sys = [H,diff(H,x)*x-diff(H,y)*y]
sys

[-x*(y + 1)^2 + y + 2, -x*(y + 1)^2 + (2*x*(y + 1) - 1)*y]

solve(sys,[x,y])

[]

# Plot a subset of V(H) in R^2
pt = parametric_plot( ((2+y)/(1+y)^2, y), (y, 0, 5/2))
pt += parametric_plot( ((2+y)/(1+y)^2, y), (y, -2, -3/2), color='red')
pt.set_aspect_ratio(1/2)
pt

# Plot these curves after taking coordinate-wise moduli, together
# with the image of the real points in the domain of convergence
pt = region_plot([x<(2-y)/(1-y)^2],(0,1/2),(0,2), incol='lightgray')
pt += region_plot([x<(2+y)/(1+y)^2],(1/2,2),(0,sqrt(3)), incol='lightgray')
pt += parametric_plot( (abs(((2+y)/(1+y)^2)), abs(y)), (y, 0, 5/2), thickness=2)
pt += parametric_plot( (abs(((2+y)/(1+y)^2)), abs(y)), (y, -2, -3/2), color='red', thickness=2)
pt.set_aspect_ratio(1/2)
pt

# Image of the above curves under the Relog map, together with points in the contour of H
pt = parametric_plot( (log(abs(((2+y)/(1+y)^2))), log(abs(y))), (y, 0, 5), color='black', thickness=2)
pt += parametric_plot( (log(abs(((2+y)/(1+y)^2))), log(abs(y))), (y, -10, 0), color='black', thickness=2)
pt += parametric_plot( (log(abs(((2+y)/(1+y)^2))), log(abs(y))), (y, 0, 5/2), thickness=2)
pt += parametric_plot( (log(abs(((2+y)/(1+y)^2))), log(abs(y))), (y, -2, -3/2), color='red', thickness=2)
pt.set_axes_range(-2,2,-2,2)
pt