Example 6.1 (A Curve of Critical Points)

A lattice path model with an infinite number of critical points.
Requirements: None

# Define the characteristic polynomial and denominator H for the lattice path model
var('x,y,z,t')
ST = [(0,i,j) for i in [-1,1] for j in [-1,1]]
ST += [(i,0,j) for i in [-1,1] for j in [-1,1]]
ST += [(i,j,0) for i in [-1,1] for j in [-1,1]]
S = add(x^i*y^j*z^k for (i,j,k) in ST)
H = 1 - t*x*y*z*S
H

-(x*y + x*z + y*z + x/y + y/x + x/z + y/z + z/x + z/y + 1/(x*y) + 1/(x*z) + 1/(y*z))*t*x*y*z + 1

# Solve the smooth critical point equations for the main diagonal direction
CPeqs = [H] + [diff(H,x)*x - diff(H,v)*v for v in [y,z,t]]
CPs = solve(CPeqs,[x,y,z,t])
CPs

[[x == 1, y == 1/4/r1, z == -1, t == r1], [x == 1, y == -1, z == 1/4/r2, t == r2], [x == -1, y == 1/4/r3, z == 1, t == r3], [x == -1, y == 1, z == 1/4/r4, t == r4], [x == 1/4/r5, y == -1, z == 1, t == r5], [x == 1/4/r6, y == 1, z == -1, t == r6], [x == 1, y == 1, z == -1, t == (1/4)], [x == 1, y == -1, z == 1, t == (1/4)], [x == 1, y == 1, z == 1, t == (1/12)], [x == -1, y == -1, z == 1, t == (-1/4)], [x == -1, y == 1, z == -1, t == (-1/4)], [x == -1, y == -1, z == -1, t == (-1/12)]]

# We get the two isolated minimal critical points
show(list(filter(lambda L: abs(t.subs(L))== 1/12, CPs)))

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x = 1, y = 1, z = 1, t = \left(\frac{1}{12}\right)\right], \left[x = \left(-1\right), y = \left(-1\right), z = \left(-1\right), t = \left(-\frac{1}{12}\right)\right]\right]$$

# And the curves of non-minimal critical points 
# (note that some points are represented multiple times)
show(list(filter(lambda L: abs(t.subs(L)) != 1/12, CPs)))

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x = 1, y = \frac{1}{4 \, r_{1}}, z = \left(-1\right), t = r_{1}\right], \left[x = 1, y = \left(-1\right), z = \frac{1}{4 \, r_{2}}, t = r_{2}\right], \left[x = \left(-1\right), y = \frac{1}{4 \, r_{3}}, z = 1, t = r_{3}\right], \left[x = \left(-1\right), y = 1, z = \frac{1}{4 \, r_{4}}, t = r_{4}\right], \left[x = \frac{1}{4 \, r_{5}}, y = \left(-1\right), z = 1, t = r_{5}\right], \left[x = \frac{1}{4 \, r_{6}}, y = 1, z = \left(-1\right), t = r_{6}\right], \left[x = 1, y = 1, z = \left(-1\right), t = \left(\frac{1}{4}\right)\right], \left[x = 1, y = \left(-1\right), z = 1, t = \left(\frac{1}{4}\right)\right], \left[x = \left(-1\right), y = \left(-1\right), z = 1, t = \left(-\frac{1}{4}\right)\right], \left[x = \left(-1\right), y = 1, z = \left(-1\right), t = \left(-\frac{1}{4}\right)\right]\right]$$